BUILD.gn

# Copyright 2014 The Chromium Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/config/host_byteorder.gni")
import("//third_party/icu/config.gni")

if (is_android) {
  import("//build/config/android/rules.gni")
}

if (is_mac) {
  import("//build/config/sanitizers/sanitizers.gni")
}

# Meta target that includes both icuuc and icui18n. Most targets want both.
# You can depend on the individually if you need to.
group("icu") {
  public_deps = [
    ":icui18n",
    ":icuuc",
  ]
}

# Shared config used by ICU and all dependents.
config("icu_config") {
  defines = [
    # Tell ICU to not insert |using namespace icu;| into its headers,
    # so that chrome's source explicitly has to use |icu::|.
    "U_USING_ICU_NAMESPACE=0",

    # We don't use ICU plugins and dyload is only necessary for them.
    # NaCl-related builds also fail looking for dlfcn.h when it's enabled.
    "U_ENABLE_DYLOAD=0",
  ]

  if (!is_component_build) {
    defines += [ "U_STATIC_IMPLEMENTATION" ]
  }

  include_dirs = [
    "source/common",
    "source/i18n",
  ]

  if (icu_use_data_file) {
    defines += [ "ICU_UTIL_DATA_IMPL=ICU_UTIL_DATA_FILE" ]
  } else {
    if (is_win) {
      defines += [ "ICU_UTIL_DATA_IMPL=ICU_UTIL_DATA_SHARED" ]
    } else {
      defines += [ "ICU_UTIL_DATA_IMPL=ICU_UTIL_DATA_STATIC" ]
    }
  }

  if (is_win) {
    defines += [ "UCHAR_TYPE=wchar_t" ]
  } else {
    defines += [ "UCHAR_TYPE=uint16_t" ]
  }
}

# Config used only by ICU code.
config("icu_code") {
  cflags = []
  defines = [
    "HAVE_DLOPEN=0",

    # Only build encoding coverters and detectors necessary for HTML5.
    "UCONFIG_ONLY_HTML_CONVERSION=1",

    # No dependency on the default platform encoding.
    # Will cut down the code size.
    "U_CHARSET_IS_UTF8=1",
  ]

  if (is_win) {
    # Disable some compiler warnings.
    cflags += [
      "/wd4005",  # Macro redefinition.
      "/wd4068",  # Unknown pragmas.
      "/wd4267",  # Conversion from size_t on 64-bits.
      # http://bugs.icu-project.org/trac/ticket/12821
      "/wd4333",  # Right shift by too large amount.
      "/utf-8",   # ICU source files are in UTF-8.
    ]
  } else if (is_linux || is_android) {
    cflags += [
      "-Wno-unused-function",
    ]
  }
  if (is_clang) {
    cflags += [
      # ICU has some code with the pattern:
      #   if (found = uprv_getWindowsTimeZoneInfo(...))
      "-Wno-parentheses",
      # ucnv2022.cpp contains three functions that are only used when
      # certain preprocessor defines are set.
      # unistr.cpp also has an unused function for non-component builds.
      "-Wno-unused-function",
    ]
  }
  if (is_clang || is_linux || is_android) {
    cflags += [
      # ICU uses its own deprecated functions.
      "-Wno-deprecated-declarations",
    ]
  }
}

component("icui18n") {
  # find  source/i18n -maxdepth 1  ! -type d  | egrep  '\.(c|cpp|h)$' |\
  # sort | sed 's/^\(.*\)$/    "\1",/'
  sources = [
    "source/i18n/affixpatternparser.cpp",
    "source/i18n/affixpatternparser.h",
    "source/i18n/alphaindex.cpp",
    "source/i18n/anytrans.cpp",
    "source/i18n/anytrans.h",
    "source/i18n/astro.cpp",
    "source/i18n/astro.h",
    "source/i18n/basictz.cpp",
    "source/i18n/bocsu.cpp",
    "source/i18n/bocsu.h",
    "source/i18n/brktrans.cpp",
    "source/i18n/brktrans.h",
    "source/i18n/buddhcal.cpp",
    "source/i18n/buddhcal.h",
    "source/i18n/calendar.cpp",
    "source/i18n/casetrn.cpp",
    "source/i18n/casetrn.h",
    "source/i18n/cecal.cpp",
    "source/i18n/cecal.h",
    "source/i18n/chnsecal.cpp",
    "source/i18n/chnsecal.h",
    "source/i18n/choicfmt.cpp",
    "source/i18n/coleitr.cpp",
    "source/i18n/collationbuilder.cpp",
    "source/i18n/collationbuilder.h",
    "source/i18n/collationcompare.cpp",
    "source/i18n/collationcompare.h",
    "source/i18n/collation.cpp",
    "source/i18n/collationdatabuilder.cpp",
    "source/i18n/collationdatabuilder.h",
    "source/i18n/collationdata.cpp",
    "source/i18n/collationdata.h",
    "source/i18n/collationdatareader.cpp",
    "source/i18n/collationdatareader.h",
    "source/i18n/collationdatawriter.cpp",
    "source/i18n/collationdatawriter.h",
    "source/i18n/collationfastlatinbuilder.cpp",
    "source/i18n/collationfastlatinbuilder.h",
    "source/i18n/collationfastlatin.cpp",
    "source/i18n/collationfastlatin.h",
    "source/i18n/collationfcd.cpp",
    "source/i18n/collationfcd.h",
    "source/i18n/collation.h",
    "source/i18n/collationiterator.cpp",
    "source/i18n/collationiterator.h",
    "source/i18n/collationkeys.cpp",
    "source/i18n/collationkeys.h",
    "source/i18n/collationroot.cpp",
    "source/i18n/collationrootelements.cpp",
    "source/i18n/collationrootelements.h",
    "source/i18n/collationroot.h",
    "source/i18n/collationruleparser.cpp",
    "source/i18n/collationruleparser.h",
    "source/i18n/collationsets.cpp",
    "source/i18n/collationsets.h",
    "source/i18n/collationsettings.cpp",
    "source/i18n/collationsettings.h",
    "source/i18n/collationtailoring.cpp",
    "source/i18n/collationtailoring.h",
    "source/i18n/collationweights.cpp",
    "source/i18n/collationweights.h",
    "source/i18n/coll.cpp",
    "source/i18n/collunsafe.h",
    "source/i18n/compactdecimalformat.cpp",
    "source/i18n/coptccal.cpp",
    "source/i18n/coptccal.h",
    "source/i18n/cpdtrans.cpp",
    "source/i18n/cpdtrans.h",
    "source/i18n/csdetect.cpp",
    "source/i18n/csdetect.h",
    "source/i18n/csmatch.cpp",
    "source/i18n/csmatch.h",
    "source/i18n/csr2022.cpp",
    "source/i18n/csr2022.h",
    "source/i18n/csrecog.cpp",
    "source/i18n/csrecog.h",
    "source/i18n/csrmbcs.cpp",
    "source/i18n/csrmbcs.h",
    "source/i18n/csrsbcs.cpp",
    "source/i18n/csrsbcs.h",
    "source/i18n/csrucode.cpp",
    "source/i18n/csrucode.h",
    "source/i18n/csrutf8.cpp",
    "source/i18n/csrutf8.h",
    "source/i18n/curramt.cpp",
    "source/i18n/currfmt.cpp",